Autor: Leon
Publikováno: 14. ledna 2002 |
Ukázka intra
Často nám posíláte všelijaké dotazy, ze
kterých vyplývá, že vám stále dělá značné problémy práce s kamerou a tvorba
intra. Rozhodl jsem se proto, že vám popíšu jedno konkrétní intro. Pakliže
ho pochopíte, dokážete pak již vytvořit cokoliv.
Jako ukázkové intro jsem použil část svého
velmi dlouhého intra z připravované kampaně pro ČSLA armádu. Vybral jsem
úsek, který zabírá jen americké jednotky a nepotřebujete pro něj tedy
addon ČSLA. Podotýkám, že v některých momentech jsem intro zjednodušil,
také proto, abych příliš neprozradil, o co v kampani půjde. Zdrojáky k
intru si můžete stánout na konci tutoriálu (pro přehrání musíte mít verzi
hry alespoň 1.30).
Ač se možná zdá zdroják na první pohled
složitý, není tomu tak. Když to zjednoduším, stačí si na začátek intra
vytvořit kameru, s tou si trochu pohrát a nakonec jí zase zničit. Navíc
hru s kamerou lze (víceméně) omezit jen na několik příkazů - CamSetPos,
CamSetTarget, CamSetFov, CamCommit a CamCommitted. Když pochopíte přesně
jejich funkci a naučíte se je společně používat, máte skoro vyhráno.
Ač si to mnoho lidí neuvědomuje, nejdůležitějším
předpokladem pro tvorbu pěkných inter jsou "režisérské" schopnosti
autora. Co je platné, že někdo ovládá práci s kamerou, když ji nedokáže
náležitě využít. Tato schopnost se bohužel příliš naučit nedá, ale když
popustíte uzdu své fantazie, jistě naněco přijdete.
Nyní už přímo k našemu intru. Pro začátek
nastíním situaci a příběh. Na jednom menším ostrůvku u Everonu je americká
základna, na které je několik nepodstatných objektů - vozidla, hlídka
u tábora, několik helipadů s vrtulníky, pár bunkrů, vlajka, oheň a pár
dalších. Z těch pro nás důležitých je to vrtulník Chinook (nazval jsem
si ho chin1) a skupina vojáků, kterým velí voják označený jako
usvelitel. Kus od tábora (někde, aby nebyl zpočátku vidět) je americký
důstojník (amik1) a kousek od něj vozidlo Hummer (hmw).
Děj bude následující. Důstojník přijede vozidlem na základnu, vystoupí
a sdělí pokyny usvelitelovi. Ten pak se svým týmem nastoupí do
Chinooku a odletí ze základny do akce.
Základní údaje již víte a můžeme tedy přistoupit přímo ke komentovanému
zdrojáku intra.
Rozbor zdrojového scriptu
V první řadě si pro jistotu nastavíme všechny
podmínky, které později využijeme, na hodnotu false, což znamená, že se
nevykonávají.
letim1=false
nastup=false
vystup=false
salute=false
gotochin=false
inchin=false
konec=false
Příkazem skiptime přesouváme čas v misi
o 2 hodiny později. Středník před příkazem ale znamená, že se příkaz nevykoná.
To proto, že v tomto ukázkovém intru nic předtím nebylo, takže je to zbytečné.
Ale v rámci celého intra pro kampaň to důležité je. Příkazy TitleCut a
TitleText byste již měli znát....
;skiptime 2
titleCut ["","BLACK IN",6]
titletext [" ... o 2 hodiny později ...","PLAIN DOWN",6]
Nyní je třeba založit kameru pro naše účely.
Pro její pozici si beru souřadnice od objektu nazvaného h3, což je v mém
případě neviditelný H (helipad). Výhoda oproti zadávání souřadnic číselně
je ta, že při ladění intra stačí s h3 na mapě pouze hýbat podle představy,
což ulehčuje práci. Použití neviditilného H pro získání souřadnic používám
často, protože to má své výhody - objekt není vidět, ale přitom vrací
v poli souřadnic všechny hodnoty (x, y, z). Často se objevuje v praxi
to, že se na mapu dá marker a souřadnice se pak získávají příkazem GetMarkerPos.
Ten však vrací pouze hodnoty x a y, takže na to pozor. Ale tím nechci
říci, že jde o špatný postup. Já jsem si jen zvykl na neviditelné H. Velmi
častá chyba je, že se souřadnice pro kamery přejímají beze změny. Jenže
většina objektů má souřadnice z = 0 nebo jen velmi málo, takže kamera
je pak nastavena ze země nebo z minimální výšky. Když k z souřadnici přičtete
nějaké ty metry, získáte tím podstatně větší přehled na mapě a vypadá
to lépe.
_CameraPos = getpos h3
_cmx = (_CameraPos select 0)
_cmy = (_CameraPos select 1)
_cmz = (_CameraPos select 2) + 35
_cam = "camera" CamCreate [_cmx,_cmy,_cmz]
_cam CameraEffect ["Internal","back"]
Příkazem CamCommit aplikujeme všechny neprovedené
předešlé změny pro kameru, číselná hodnota určuje, za jak dlouho se tak
stane. Hodnota 0 znamená, že okamžitě, při konkrétních hodnotách dochází
k přechodu mezi kamerovými změnami. První použití tohoto příkazu nám aplikuje
vznik kamery. Ihned poté příkazem CamSetTarget zaměříme kameru na oheň
(je pojmenovaný fire2) na základně a příkazem CamSetFov nastavíme
úroveň přiblížení na něj. Defaultní hodnota je tuším 0.7, takže hodnotou
0.6 si ho trochu přiblížíme.Až doposud se ale tyto příkazy neprojevily,
protože se tak stane až po příkazu CamCommit! V tomto případě (s hodnotou
4 sekundy) se po jeho vykonání stane to, že kamera přejde plynule během
4 vteřin na cíl fire2 a trochu ho přiblíží. Poslední příkaz @CamCommitted
je příkaz, jehož význam si mnoho lidí vůbec neuvědomuje. Způsobuje to,
že se další příkazy začnou vykonávat až poté, co kamera vykoná požadované
věci. Je dobré ho používat právě po příkazu CamCommit. Více nad tímto
příkazem raději nepřemýšlejte, ale takto ho používejte často. Zkazit tím
nic nemůžete.
_cam CamCommit 0
_cam CamSetTarget fire2
_cam CamSetFov 0.6
_cam CamCommit 4
@camCommitted _cam
Teď změníme hodnotu podmínky nastup
na true, čímž se spustí akce, která je touto podmínkou podmíněna. V tomto
případě je to podmínka ve waypointu vojaka amik1 pro nástup do
Hummeru.
nastup=true
Následující 4 vteřiny se nic neděje a pak
se na obrazovce pomalu (během 5 vteřin, viz poslední hodnota) objevuje
nápis. Pak nastavíme cíl pro kameru na americkou vlajku v táboře a nastavíme
přiblížení na hodnotu 0.18 (což je teď relativně velké přiblížení). Příkazem
CamCommit tyto příkazy aplikujeme - v praxi to vypadá tak, že se cíl kamery
mění za tu dobu z ohně na vlajku a zároveň si jí přibližuje.
~4
titletext ["Americká základna,\n ostrov východně od Everonu","PLAIN
DOWN",5]
_cam CamSetTarget vlajkaus
_cam CamSetFov 0.18
_cam CamCommit 4
@camCommitted _cam
Chvilku posečkáme a pak podobným postupem
změníme cíl na Chinook chin1 s tím, že se pohled zase naopak trochu
oddálil.
~2
_cam CamSetTarget chin1
_cam CamSetFov 0.45
_cam CamCommit 2
@camCommitted _cam
Po chvilce pohled ještě více oddálíme a
příkazem TitleText bez textu docílíme toho, že nám předčasně zmizí z obrazovky
nápis.
~3
_cam CamSetFov 0.55
_cam CamCommit 4
@camCommitted _cam
titletext ["","PLAIN DOWN",5]
Nyní se kamera natočí k přijíždějícímu
Hummeru (hmw) s vojákem amik1. Po chvilce si pak vozidlo
přiblíží na hodnotu 0.15.
_cam CamSetTarget hmw
_cam CamCommit 2
~3
_cam CamSetFov 0.15
_cam CamCommit 3
@camCommitted _cam
Podmínka vystup je nastavena na
waypointu vojáka amik1, kam má dojet vozidlem (při aktivaci - vystup
= true). V momentě, kdy se tak stane, nabývá podmínka hodnotu true a tím
se aktivuje. Příkazem @vystup si zajistíme, že se vykonávání scriptu pozastaví
právě do okamžiku, než nabude vystup hodnoty true.
@vystup
Po vystoupení vojáka z vozidla se kamera
přepne něj a ještě více si ho přiblíží...
_cam CamSetTarget amik1
_cam CamSetFov 0.1
_cam CamCommit 4
@camCommitted _cam
Vedoucí skupinky vojáků v táboře usvelitel
a amik1, který právě přijel autem, dojdou díky waypointům téměř
k sobě. Během toho je vhodné příkazem DoWatch nastavit, aby se po sobě
vojáci dívali.
usvelitel DoWatch amik1
amik1 DoWatch usvelitel
S dalšími akcemi počkáme až do okamžiku,
kdy bude mít proměnná salute hodnotu true. To se stává podobně
jako předtím v momentě, kdy amik1 dojde na další waypoint.
@salute
Nyní si přesuneme kameru jinam (příkazem
CamSetPos). Zjistíme si souřadnice vojáka amik1 a kameru umístíme
trochu za něj a nad něj tak, abychom viděli na usvelitele a jeho
tým.
_CameraPos = GetPos amik1
_cmx = (_CameraPos select 0) + 6
_cmy = (_CameraPos select 1) - 6
_cmz = (_CameraPos select 2) + 4
_cam CamSetPos [_cmx,_cmy,_cmz]
_cam CamSetTarget usvelitel
_cam CamSetFov 0.4
_cam CamCommit 3
@camCommitted _cam
V tomto okamžiku následuje rozhovor obou
vojáků. Pro účely tohoto tutoriálu ale omezíme jejich konverzaci na pár
gest. Více o gestech jsme psali v minulém tutoriálu.
~1
usvelitel switchmove "EffectStandSalute"
~1
usvelitel switchmove "FXStandAtt"
amik1 switchmove "EffectStandSalute"
~5
usvelitel switchmove "FxStandStill"
~10
Podmínka gotochin je pro nástup
týmu vojáků vedeného usvelitelem do vrtulníku Chinook. Změnou na
hodnotu true se tento tým jde naložit do vrtulníku. Amik1 stojí
a dívá se za nimi.
gotochin=true
amik1 DoWatch usvelitel
Opět plynule změníme polohu kamery za vrtulník
tak, abychom viděli přesun a nástup týmu vojáků do něj. Pohled trvá až
do okamžiku, kdy jsou všichni vojáci naloženi (waypoint - při aktivaci
- inchin = true).
~5
_CameraPos = GetPos chin1
_cmx = (_CameraPos select 0) + 50
_cmy = (_CameraPos select 1) + 50
_cmz = (_CameraPos select 2) + 20
_cam CamSetPos [_cmx,_cmy,_cmz]
_cam CamCommit 3
~5
_cam CamSetTarget usvelitel
_cam CamSetFov 0.35
_cam CamCommit 3
@camCommitted _cam
@inchin
Nyní dáme pokyn vrtulníku, aby někam odletěl.
V originální verzi to mám udělané přes waypointy, ale protože tam mám
další vazby, bude nám teď stačit, když se vrtulník začne přesouvat na
pozici objektu h4 (opět neviditelný H) příkazem DoMove.
chin1 DoMove GetPos h4
Vrtulník startuje a my přesuneme kameru
plynule za amika1 tak, abychom viděli start vrtulníku. Amik1
se při tom kouká na odlétající vrtulník.
~2
_CameraPos = GetPos amik1
_cmx = (_CameraPos select 0) - 20
_cmy = (_CameraPos select 1) + -5
_cmz = (_CameraPos select 2) + 2
_cam CamSetPos [_cmx,_cmy,_cmz]
_cam CamSetTarget chin1
_cam CamSetFov 0.3
_cam CamCommit 4
@camCommitted _cam
amik1 DoWatch chin1
Těsně pod odlepení vrtulníku od země zaměříme
cíl kamery opět na amika1, který jim k odletu zasalutuje. Pak se
kamera přepne zpět na odlétávající vrtulník.
~8
_cam CamSetTarget amik1
_cam CamSetFov 0.2
_cam CamCommit 2
@camCommitted _cam
~2
amik1 switchmove "EffectStandSalute"
~3
_cam CamSetTarget chin1
_cam CamSetFov 0.5
_cam CamCommit 3
@camCommitted _cam
Nyní následuje smyčka příkazů. Během ní
se vždy nastaví poloha kamery kousek za vrtulník, přičemž kamera míří
pohledem na amik1. Smyčka se bude opakovat, dokud hodnota letim1
nenabyde hodnoty true. To se stane poté, co vrtulník aktivuje spínač na
své cestě (při aktivaci - letim1 = true). Tím se docílí efektu, kdy vidíte
vzdalující se základnu (jakoby) z vrtulníku. Ještě bych chtěl podotknout,
že jméno podmínky nemusí být vůbec shodné s návěštím (#). Spíš by tomu
mělo být naopak, aby se to nepletlo. Já jsem si na to ale zvykl a vyznám
se v tom.
#letim1
_CameraPos = GetPos chin1
_cmx = (_CameraPos select 0) + 5
_cmy = (_CameraPos select 1) + 45
_cmz = (_CameraPos select 2) + 10
_cam CamSetPos [_cmx,_cmy,_cmz]
_cam CamSetTarget amik1
_cam CamCommit 0
~0.01
? NOT (letim1) : goto "letim1"
V momentě, kdy se sepne první spínač, se
kamera zastaví a plynule přejde pohledem na stále se vzdalující vrtulník
a po nějakou dobu se za ním dívá.
_cam CamSetTarget chin1
_cam CamCommit 4
@camCommitted _cam
~10
Tím můžeme intro ukončit, přičemž je důležité
zničit po sobě kameru.
_cam CameraEffect ["Terminate","Back"]
CamDestroy _cam
Misi ukončíme nastavením proměnné konec
na true. Tím se nám aktivuje spínač, který má nastaven typ Konec č.1 a
jako podmínku má konec.
konec = true
exit
Závěr
Doufám, že jste vše pochopili, pokud ne, směřujte dotazy do
diskusí.
Na závěr
vám jako vždy dávám k dispozici zdrojáky této mise, tady jsou:
Stáhnout
zdrojovou misi Int2 (vyžaduje verzi hry minimálně 1.30)
Leon
připravil: Leon |
přidat
komentář do diskusního fóra |
|